XML操作脚本例子

蓝星际语音平台脚本例子

这些例子都比较简单, 有些比较有趣，您很容易看明白，仔细阅读源程序可以让您迅速入门，也会提高您的水平。
每个例子都有一个说明文档，请您在运行例子之前阅读它。
请将蓝星际平台程序拷贝到相应的目录之下，然后运行。因为有些脚本使用了相对路径，所以建议脚本文件和蓝星际平台程序放在相同的目录。

XML操作

说明：

XmlTest.bss - 使用XML操作函数的例子
XmlTools.bss - XML操作函数集, 可以被其它脚本包含
XmlTools封装了一组操作XML的函数，包括生成、分解XML数据的函数，具体说明请参考源程序.

使用XML操作函数的例子：

// 文件名：XmlTest.bss
// 测试XML操作例程

// bluesen 2005.10.21
// BlueSpace Co. Shenzhen
// http://www.bluespace.com.cn/koodoo
// zhudn@bluespace.com.cn

#include <XmlTools.bss>  // 包含Xml操作函数集


// 测试生成XML串1
// "hello world" --> "<p>hello world</p>"
s1 = MakeXmlNode("hello world", "p", 0);


// 测试生成XML串2
// "BlueSpace Koodoo" --> "<font color="red" size="12">BlueSpace Koodoo</font>"
aList["color"] = "red";
aList["size"] = "12";
s = "BlueSpace Koodoo";
s2 = MakeXmlNode(s, "font", aList);


// 更复杂的例子，生成组合的XML项
s = "首页";
aList = 0;
aList["title"] = "首页";
s = MakeXmlNode(s, "acronym", aList);

aList = 0;
aList["href"] = "index.htm";
s = MakeXmlNode(s, "a", aList);

aList = 0;
aList["class"] = "phome";
s3 = MakeXmlNode(s, "p", aList);
// 最后的结果是: <p class="phome"><a href="index.htm"><acronym title="首页">首页</acronym></a></p>


// 测试分解XML串
s4 = "<name sex=\"1\" co=\"BlueSpace Co.\" email = \"bluesen@sina.com\">bluesen</name>";
tag = "";
data = "";
attrs = 0;
GetXmlNode(s4, data, tag, attrs);

// 测试辅助函数
m = 0;
lstIsData = 0;
n = ParseXmlStr(s1, m, lstIsData);
tag = "";
attrs = 0;
GetXmlAttrs(m[0], tag, attrs);

m = 0;
lstIsData = 0;
ParseXmlStr(s2, m, lstIsData);
tag = "";
attrs = 0;
GetXmlAttrs(m[0], tag, attrs);

m = 0;
lstIsData = 0;
ParseXmlStr(s3, m, lstIsData);
tag = "";
attrs = 0;
GetXmlAttrs(m[0], tag, attrs);

return(0);

XML操作函数集

// 文件名: XmlTools.bss
// XML操作例程
// 这是一组轻量级的XML操作函数，完全用Koodoo语言实现，比较简单，也不占用什么资源
// 和文件操作函数结合就可以读写XML文件了
// 在应用脚本中包含本文件就可以使用例程，如：
// #include <XmlTools.bss>

// 封装了一组操作XML的函数，
// 主要接口如下：
// 1. 生成XML项: MakeXmlNode(data, tag, aList)
//    将原始串生成为带坚括号的XML串, 可以指定属性表
// 2. 分解XML项: GetXmlNode(xmlStr, data, tag, aList)
//    相当于MakeXmlNode()的反函数

// 辅助接口如下：
// 3. 分解原始XML串: ParseXmlStr(xmlStr, m, lstIsData)
//    将XML串分解成字符串数组
// 4.分解属性字符串: GetXmlAttrs(str, tag, attrs)

// 朱东宁(bluesen) 2005.10.21
// BlueSpace Co. Shenzhen
// http://www.bluespace.com.cn/koodoo
// zhudn@bluespace.com.cn


// --------------------------------------
// 分解原始XML串
// 参数：str - 输入的原始内容
//       m - 内容数组
//       lstIsData - 逻辑数组，成员true表示是数据，否则表示为tag和属性内容
// 返回值：>0: 数组长度，0: 不成功, <0: 有错误
function ParseXmlStr(str, m, lstIsData)
{
  n = 0;
  s = "";
  for(c in str)
  {
     if( c=="<" )
     {
        if( s!="" )
        {
           m[n] = s;
           lstIsData[n] = true;
           n ++;
        }

        s = "";
     }
     else if( c==">" )
     {
        m[n] = s;
        lstIsData[n] = false;
        n ++;

        s = "";
     }
     else if( s=="" && (c==" " || c=="\t" || c=="\n") )
        continue;
     else
        s = s + c;
  }
  return(n);
}

// 分解属性字符串
// 参数：str - 输入串
//       tag - 标志值
//       attrs - 属性map
// 返回值：0 - 起始标志, 1 - 结束标志, 2 - 空内容的属性, 3 - 注释或?, <0 - 错误
function GetXmlAttrs(str, tag, attrs)
{
  attrs = 0;
  tag = "";

  // 将输入串分解到数组
  isStr = false;
  s = "";
  m = 0;
  n = 0;
  for(c in str)
  {
     if( c=="\"" )
     {
        isStr = !isStr;
        if( s!="" )
        {
           m[n] = s;
           n ++;
        }
        s = "";
        continue;
     }

     if( isStr )
     {
        s = s + c;
        continue;
     }
     
     if( (c=="!" || c=="?") && s=="" )
     {
        m = 0;
        return(3);
     }

     if( c=="/" || c=="=" )
     {
        if( s!="" )
        {
           m[n] = s;
           n ++;
        }
        m[n] = c;
        n ++;
        s = "";
     }
     else if( c==" " || c=="\t" || c=="\n" )
     {
        if( s!="" )
        {
           m[n] = s;
           n ++;
           s = "";
        }
     }
     else
        s = s + c;
  }

  if( s!="" )
  {
     m[n] = s;
     n ++;
     s = "";
  }
  
  // 处理结果
  if( n>0 )
  {
    if( m[0]=="/" )
    {
       tag = m[1];
       m = 0;
       return(1);
    }
    tag = m[0];
  }
  else
    return(-1);
   
  ret = 0; 
  for(i=1; i<n; i++)
  {
     s = m[i];
     if( s=="=" )
     {
        index = m[i-1];
        i ++;
        attrs[index] = m[i];
     }
     if( s=="/" )
     {
        ret = 2;
     }
  }

  m = 0;
  return(ret);
}

// 分解XML项
// 参数：str - 输入的原始内容
//       data - 数据
//       tag - 标志
//       aList - 属性数组，每个成员的下标为属性名称，值为属性的值
// 返回值：>=0: 成功, <0: 有错误
function GetXmlNode(str, data, tag, aList)
{
 data = "";
 tag = "";
 aList = 0;

 m = 0;
 lstIsData = 0;
 n = ParseXmlStr(str, m, lstIsData);

 if( n>0 )
 {
    GetXmlAttrs(m[0], tag, aList);
    if( n>1 )
    {
       if( lstIsData[1] )
          data = m[1];
    }
 }
 m = 0;
 return(n);
}


// 生成XML项
// 参数：s - 原始内容
//       tag - 标志
//       aList - 属性数组，每个成员的下标为属性名称，值为属性的值
function MakeXmlNode(s, tag, aList)
{
  a = "";
  for(b in aList)
     a = a + " " + b + "=\"" + aList[b] + "\"";
  return( "<" + tag + a + ">" + s + "</" + tag + ">" );
}
// --------------------------------------

下载：

XML操作函数的例子＋XML函数集脚本

Koodoo脚本示例

蓝星际语音平台 脚本例子

XML操作

蓝星际语音平台脚本例子